@echo off
echo.
echo  Les droits Administrateur sont requis pour lancer %~n0
echo.
echo  Detection en cours...
echo.
net session >nul 2>&1
if %errorLevel% == 0 (
		echo  OK:  Les droits Administrateur sont garantis.
		echo.
) else (
		echo  ECHEC: Les droits actuels sont insuffisants.
		echo.
		echo  Appuyez sur une touche pour quitter...
		pause >nul
		exit
)
set serviceNom=AbleTaskKill
set serviceExe=AbleTaskKill.exe
:menu
echo.
echo  Commandes disponibles:
echo.
echo  H) Afficher les commandes
echo  I) Installer le service
echo  U) Desinstaller le service
echo  A) Afficher le status du service

echo  D) Demarrer le service
echo  X) Stopper le service

echo  T) Lancer le Gestionnaire des taches (taskmgr.exe)
echo  S) Lancer le Gestionnaire des services (services.msc)

echo  Q) Quitter
echo.
choice /t 60 /d Q /c HIUADXTSQ /m "> Quelle action voulez-vous faire ? "
cls
echo.
if %errorlevel% == 1 set param=/help
if %errorlevel% == 2 set param=/install
if %errorlevel% == 3 set param=/uninstall
if %errorlevel% == 4 set param=/status

if %errorlevel% == 5 (
	net start %serviceNom%
	goto :menu
)
if %errorlevel% == 6 (
	net stop %serviceNom%
	goto :menu
)

if %errorlevel% == 7 (
	start taskmgr.exe
	goto :menu
)

if %errorlevel% == 8 (
	start services.msc
	goto :menu
)

if %errorlevel% == 9 exit

set dossier=%~dp0

echo %dossier%%serviceExe% %param%
echo.
call %dossier%%serviceExe% %param%
echo.
goto :menu
exit
